home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / asm / sound.s < prev    next >
Encoding:
Text File  |  1998-10-04  |  5.2 KB  |  262 lines
  1. ;
  2. ; sound.s - an ACE linked library module: sound routines. 
  3. ; Copyright (C) 1998 David Benn
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ;
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ;
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ;
  19. ; Author: David J Benn
  20. ;   Date: 15th,16th May 1992,
  21. ;         6th,30th June 1992,
  22. ;      4th,5th,6th,7th,19th,22nd July 1992
  23. ;      9th August 1992,
  24. ;      5th December 1992,
  25. ;      1st March 1993,
  26. ;      31st October 1993,
  27. ;      3rd April 1994
  28. ;
  29.  
  30.     ; sound xdefs
  31.  
  32.     xdef    _sound
  33.     xdef    _wave
  34.       xdef    _beep
  35.  
  36.  
  37.     ; * XREFS *
  38.  
  39.     xref    _initialise_waveform_data
  40.     xref    _waveformaddr0
  41.     xref    _waveformaddr1
  42.     xref    _waveformaddr2
  43.     xref    _waveformaddr3
  44.     xref    _wavelen0
  45.     xref    _wavelen1
  46.     xref    _wavelen2
  47.     xref    _wavelen3
  48.     xref    _sinwavedata
  49.  
  50.     ; dos library
  51.     xref    _DOSBase
  52.     xref    _LVODelay
  53.  
  54.     ; math library 
  55.     xref    _MathBase
  56.     xref    _LVOSPFix
  57.     xref    _LVOSPMul
  58.     xref    _LVOSPCmp
  59.     
  60.     SECTION sound_code,CODE
  61.  
  62. ; *** SOUND ROUTINES ***
  63.  
  64. ;
  65. ; SOUND - play a sound. d0=period; d1=duration (ffp); d2=volume; d3=voice.
  66. ;    - the hardware is programmed directly.
  67. ;
  68. _sound:
  69.     ; save parameters
  70.     move.w    d0,_period        ; 124..32767
  71.     move.l  d1,_duration        ; 0..999 (somewhat arbitrary)
  72.     move.w    d2,_volume        ; 0..64
  73.     move.w    d3,_voice        ; 0..3
  74.      
  75.     ; check parameters -> quit if any are out of range
  76.     
  77.     ; period 
  78.     cmpi.w    #124,_period
  79.     blt    _quitsound        ; can't be > 32767 by virtue of
  80.                     ; being a short integer
  81.  
  82.     ; duration    
  83.     move.l    _MathBase,a6    
  84.     move.l    _duration,d0
  85.     move.l    #0,d1
  86.     jsr    _LVOSPCmp(a6)        ; duration < 0?
  87.     blt    _quitsound
  88.     move.l    _duration,d0
  89.     move.l    #$f9c0004a,d1        
  90.     jsr    _LVOSPCmp(a6)        ; duration > 999?
  91.     bgt    _quitsound
  92.     
  93.     ; volume 
  94.     cmpi.w    #0,_volume
  95.     blt    _quitsound
  96.     cmpi.w    #64,_volume
  97.     bgt    _quitsound
  98.  
  99.     ; which audio channel?
  100.     cmpi.w    #0,d3
  101.     bne.s    _aud1
  102.  
  103.     ; audio channel 0
  104.     move.l    _dmactrl,a1
  105.     move.w    #1,(a1)            ; disable DMA
  106.     move.l    _audio0,a0
  107.     move.l    _waveformaddr0,(a0)    ; address of waveform table
  108.     move.w    _wavelen0,4(a0)        ; # of words in table
  109.     move.w    _period,6(a0)        ; period (read in rate)
  110.     move.w    _volume,8(a0)        ; volume
  111.     move.w    #$8201,(a1)        ; enable DMA (start sound)
  112.     jsr    _sound_delay
  113.     move.l    _dmactrl,a1        ; putchar may have corrupted a1
  114.     move.w    #1,(a1)
  115.     rts
  116.  
  117. _aud1:
  118.     cmpi.w    #1,d3
  119.     bne.s    _aud2
  120.     move.l    _dmactrl,a1
  121.     move.w    #2,(a1)
  122.     move.l    _audio1,a0
  123.     move.l    _waveformaddr1,(a0)
  124.     move.w    _wavelen1,4(a0)
  125.     move.w    _period,6(a0)        
  126.     move.w    _volume,8(a0)
  127.     move.w    #$8202,(a1)
  128.     jsr    _sound_delay
  129.     move.l    _dmactrl,a1
  130.     move.w    #2,(a1)
  131.     rts
  132.  
  133. _aud2:
  134.     cmpi.w    #2,d3
  135.     bne.s    _aud3
  136.     move.l    _dmactrl,a1
  137.     move.w    #4,(a1)
  138.     move.l    _audio2,a0
  139.     move.l    _waveformaddr2,(a0)
  140.     move.w    _wavelen2,4(a0)
  141.     move.w    _period,6(a0)        
  142.     move.w    _volume,8(a0)
  143.     move.w    #$8204,(a1)
  144.     jsr    _sound_delay
  145.     move.l    _dmactrl,a1
  146.     move.w    #4,(a1)
  147.     rts
  148.         
  149. _aud3:
  150.     cmpi.w    #3,d3
  151.     bne    _quitsound
  152.     move.l    _dmactrl,a1
  153.     move.w    #8,(a1)
  154.     move.l    _audio3,a0
  155.     move.l    _waveformaddr3,(a0)
  156.     move.w    _wavelen3,4(a0)
  157.     move.w    _period,6(a0)        
  158.     move.w    _volume,8(a0)    
  159.     move.w    #$8208,(a1)
  160.     jsr    _sound_delay
  161.     move.l    _dmactrl,a1
  162.     move.w    #8,(a1)
  163.     rts
  164.     
  165. _sound_delay:
  166.     move.l    _MathBase,a6
  167.     move.l    _duration,d1        ; duration
  168.     move.l    #$afced942,d0        ; 2.747
  169.     jsr    _LVOSPMul(a6)        ; ticks = duration*2.747
  170.     jsr    _LVOSPFix(a6)        ; ticks = (int)ticks
  171.     move.l    _DOSBase,a6
  172.     move.l    d0,d1            ; ticks
  173.     jsr    _LVODelay(a6)
  174.     rts        
  175.  
  176. _quitsound:            
  177.     rts
  178.  
  179. ;
  180. ; WAVE - create a new waveform table for SOUND command.
  181. ;     d0=voice; a0=address of waveform table; d1=length of waveform table.
  182. ;
  183. _wave:
  184.     ; halve # of bytes in waveform table to give # of words
  185.     divu    #2,d1    
  186.  
  187.     ; is it a SIN wave? (address=0)
  188.     cmpa.l    #0,a0
  189.     bne.s    _which_audio        ; -> NO
  190.     lea    _sinwavedata,a0        ; -> YES
  191.     move.w    #16,d1            ; length of sine waveform table
  192.     
  193. _which_audio:
  194.     ; which audio channel?
  195.     cmpi.w    #0,d0
  196.     bne.s    _waud1
  197.     move.l    a0,_waveformaddr0
  198.     move.w    d1,_wavelen0
  199.     rts
  200.  
  201. _waud1:
  202.     cmpi.w    #1,d0
  203.     bne.s    _waud2
  204.     move.l    a0,_waveformaddr1
  205.     move.w    d1,_wavelen1
  206.     rts
  207.  
  208. _waud2:
  209.     cmpi.w    #2,d0
  210.     bne.s    _waud3
  211.     move.l    a0,_waveformaddr2
  212.     move.w    d1,_wavelen2
  213.     rts
  214.  
  215. _waud3:
  216.     cmpi.w    #3,d0
  217.     bne.s    _quitwave
  218.     move.l    a0,_waveformaddr3
  219.     move.w    d1,_wavelen3
  220.     rts
  221.  
  222. _quitwave:    
  223.     rts
  224.  
  225. ;
  226. ; BEEP - issues a 0.12 second pulse through voice 0.
  227. ;      - save and restore all registers since this
  228. ;        routine can be called from C (see Ustringprint).
  229. ;
  230. _beep:
  231.     movem.l    d1-d7/a0-a6,-(sp)
  232.     move.w    #505,d0        
  233.     move.l    #$8ccccd42,d1    ; duration of 0.12 seconds.
  234.     move.w    #64,d2        ; full volume
  235.     move.w    #0,d3        ; voice 0
  236.     jsr    _sound
  237.     movem.l    (sp)+,d1-d7/a0-a6
  238.     rts
  239.  
  240. ; *************************
  241.  
  242.     SECTION sound_data,DATA
  243.  
  244. ; * sound & wave *
  245. _audio0:        dc.l  $dff0a0
  246. _audio1:        dc.l  $dff0b0
  247. _audio2:        dc.l  $dff0c0
  248. _audio3:        dc.l  $dff0d0
  249. _dmactrl:        dc.l  $dff096
  250.  
  251. ; *************************
  252.  
  253.     SECTION sound_mem,BSS
  254.  
  255. ; * sound *
  256. _period:        ds.w 1
  257. _duration:        ds.l 1
  258. _volume:        ds.w 1
  259. _voice:            ds.w 1
  260.  
  261.     END
  262.